﻿ If VersionLessThan 1.1.2
	Message "Для установки требуется OBMM версии 1.1.2 или выше."
	FatalError
EndIf

IfNot ScriptExtenderNewerThan 0.0.18.3
	IfNot DialogYesNo "Мод требует наличия OBSE v0018 beta 4 и выше. OBSE должен быть установлен ДО установки этого мода.%NewLine%%NewLine%Продолжить?" "ВНИМАНИЕ - ТРЕБУЕТСЯ OBSE"
		FatalError
	EndIf
EndIf

AllowRunOnLines

DontInstallAnyDataFiles

CopyPlugin "00 Core\\Map Marker Overhaul.esp" "Map Marker Overhaul.esp"

If DataFileExists "DLCShiveringIsles.esp"
	CopyPlugin "02 SI additions\\Map Marker Overhaul - SI additions.esp" "Map Marker Overhaul - SI additions.esp"
EndIf

SelectWithPreview "Выберите стиль иконок",\
	"Оригинальные иконки Oblivion" "images\\Vanilla.jpg",\
	"Иконки Elven Map Redux" "images\\Elven.jpg",\
	"Иконки Adny's Map", "images\\Adny.jpg",\
	"Иконки Colored Map", "images\\Colored.jpg",\
	"Иконки Borderless Map", "images\\Borderless.jpg",\
	"Иконки Vacuity's Copper", "images\\copper.jpg",\
	"Иконки Vacuity's Iron", "images\\iron.jpg",\
	"Иконки Vacuity's Gold+Silver", "images\\Gold.jpg"
	Case Оригинальные иконки Oblivion
		CopyDataFolder "01 Vanilla Icons\\Textures" "Textures" True
	Break
	Case Иконки Elven Map Redux
		CopyDataFolder "01 Elven Icons\\Textures" "Textures" True
	Break
	Case Иконки Adny's Map
		CopyDataFolder "01 Adny's Icons\\Textures" "Textures" True
	Break
	Case Иконки Colored Map
		CopyDataFolder "01 Colored Icons\\Textures" "Textures" True
	Break
	Case Иконки Borderless Map
		CopyDataFolder "01 Borderless Icons\\Textures" "Textures" True
	Break
	Case Иконки Vacuity's Copper
		CopyDataFolder "01 Vacuity's Copper Icons\\Textures" "Textures" True
	Break
	Case Иконки Vacuity's Iron
		CopyDataFolder "01 Vacuity's Iron Icons\\Textures" "Textures" True
	Break
	Case Иконки Vacuity's Gold+Silver
		CopyDataFolder "01 Vacuity's Gold+Silver Icons\\Textures" "Textures" True
	Break
EndSelect


SetVar AW 0
SetVar WS 0
SetVar DT 0
SetVar RT 0
SelectMany "Выберите тип новых маркеров карты, которые будут добавлены",\
	"|Айлейдские колодцы" "|Дорожные святилища" "|Камни судьбы" "|Рунные камни"
	Case Айлейдские колодцы
		SetVar AW 1
	Break
	Case Дорожные святилища
		SetVar WS 1
	Break
	Case Камни судьбы
		SetVar DT 1
	Break
	Case Рунные камни
		SetVar RT 1
	Break
EndSelect

If Equal %DT% 1
	If Equal %RT% 1
		SetVar ST 3
	Else
		SetVar ST 1
	EndIf
Else
	If Equal %RT% 1
		SetVar ST 2
	Else
		SetVar ST 0
	EndIf
EndIf


SetVar houses 9
SetVar docks 3
SetVar stables 8
SetVar castles 3
SetVar farms 9
SetVar chapels 9
SetVar merchants 8
SetVar SIgates 7
SetVar playerHouses 3
SetVar sewers 2

SelectMany "Новые иконки для следующих маркеров",\
	"|Дом",\
	"|Док/Порт",\
	"|Конюшня",\
	"|Замок",\
	"|Ферма",\
	"|Часовня",\
	"|Торговец",\
	"|Врата безумия",\
	"|Дом игрока",\
	"|Канализация"
	Case Дом
		SetVar houses 18
	Break
	Case Док/Порт
		SetVar docks 23
	Break
	Case Конюшня
		SetVar stables 24
	Break
	Case Замок
		SetVar castles 25
	Break
	Case Ферма
		SetVar farms 26
	Break
	Case Часовня
		SetVar chapels 27
	Break
	Case Торговец
		SetVar merchants 28
	Break
	Case Врата безумия
		SetVar SIgates 30
	Break
	Case Дом игрока
		SetVar playerHouses 18
	Break
	Case Канализация
		SetVar sewers 31
	Break
EndSelect

Select "Выберите правило поведения маркеров при активации", \
	"Быстрое путешествие по левому клику, переименование маркеров по Ctrl+клик",\
	"MMO активируется по левому клику, быстрое путешествие Ctrl+клик",\
	"MMO активируется по левому клику, быстрое путешествие отключено",\
	"Быстрое путешествие по левому клику, MMO по правому клику"
	Case Быстрое путешествие по левому клику, переименование маркеров по Ctrl+клик
		SetVar FTM 0
	Break
	Case MMO активируется по левому клику, быстрое путешествие Ctrl+клик
		SetVar FTM 1
	Break
	Case MMO активируется по левому клику, быстрое путешествие отключено
		SetVar FTM 2
	Break
	Case Быстрое путешествие по левому клику, MMO по правому клику
		SetVar FTM 3
	Break
EndSelect


SetVar fastTravelmaxSingleDistance 0
SetVar fastTravelTimeRestriction 0
SetVar fastTravelmaxDistance 0
SetVar fastTravelRideFactor 1.2
IfNot Equal %FTM% 2
	If DialogYesNo "Хотите ли вы ограничить максимально возможную дистанцию для Быстрого путешествия?%NewLine%%NewLine%Вы можете задать максимальную дистанцию для каждого отдельного из путешествий, максимально возможную дистанцию, накопленную быстрыми путешествиями за определенный промежуток времени, или же оба параметра сразу.%NewLine%%NewLine%Дистанция измеряется в 'ячейках', например, дистанция между Корролом и Имперским городом равна 25 ячеек." "Ограничения для быстрого путешествия"
		Select "Максимальная дистанция для отдельного быстрого путешествия",\
			"Без ограничений", "50 ячеек", "30 ячеек", "20 ячеек", "15 ячеек", "10 ячеек", "5 ячеек", "3 ячейки"
			Case Без ограничений
				SetVar fastTravelmaxSingleDistance 0
			Break
			Case 50 ячеек
				SetVar fastTravelmaxSingleDistance 50
			Break
			Case 30 ячеек
				SetVar fastTravelmaxSingleDistance 30
			Break
			Case 20 ячеек
				SetVar fastTravelmaxSingleDistance 20
			Break
			Case 15 ячеек
				SetVar fastTravelmaxSingleDistance 15
			Break
			Case 10 ячеек
				SetVar fastTravelmaxSingleDistance 10
			Break
			Case 5 ячеек
				SetVar fastTravelmaxSingleDistance 5
			Break
			Case 3 ячейки
				SetVar fastTravelmaxSingleDistance 3
			Break
		EndSelect
		
		SelectWithDescriptions "Время ожидания до следующего быстрого путешествия",\
			"Без ограничений" "Вы сможете пользоваться быстрым путешествием в любое время.",\
			"1 час" "Вы должны подождать как минимум 1 час, чтобы быстрое путешествие снова стало доступным, если вы пользовались им слишком часто",\
			"6 часов" "Вы должны подождать как минимум 6 часов, чтобы быстрое путешествие снова стало доступным, если вы пользовались им слишком часто",\
			"12 часов" "Вы должны подождать как минимум 12 часов, чтобы быстрое путешествие снова стало доступным, если вы пользовались им слишком часто",\
			"24 часа" "Вы должны подождать как минимум 24 часа, чтобы быстрое путешествие снова стало доступным, если вы пользовались им слишком часто",\
			"48 часов" "Вы должны подождать как минимум 48 часов, чтобы быстрое путешествие снова стало доступным, если вы пользовались им слишком часто",\
			"96 часов" "Вы должны подождать как минимум 96 часов, чтобы быстрое путешествие снова стало доступным, если вы пользовались им слишком часто"
			Case Без ограничений
				SetVar fastTravelTimeRestriction 0
			Break
			Case 1 час
				SetVar fastTravelTimeRestriction 1
			Break
			Case 6 часов
				SetVar fastTravelTimeRestriction 6
			Break
			Case 12 часов
				SetVar fastTravelTimeRestriction 12
			Break
			Case 24 часа
				SetVar fastTravelTimeRestriction 24
			Break
			Case 48 часов
				SetVar fastTravelTimeRestriction 48
			Break
			Case 96 часов
				SetVar fastTravelTimeRestriction 96
			Break
		EndSelect
			
		IfNot Equal %fastTravelTimeRestriction% 0
			SelectWithDescriptions "Максимальная допустимая накопленная дистанция за %fastTravelTimeRestriction% час(ов)",\
				"50 ячеек", "Вы не сможете пользоваться быстрым путешествием, если накопленная путешествиями дистанция превысит 50 ячеек",\
				"30 ячеек", "Вы не сможете пользоваться быстрым путешествием, если накопленная путешествиями дистанция превысит 30 ячеек",\
				"20 ячеек", "Вы не сможете пользоваться быстрым путешествием, если накопленная путешествиями дистанция превысит 20 ячеек",\
				"15 ячеек", "Вы не сможете пользоваться быстрым путешествием, если накопленная путешествиями дистанция превысит 15 ячеек",\
				"10 ячеек", "Вы не сможете пользоваться быстрым путешествием, если накопленная путешествиями дистанция превысит 10 ячеек",\
				"5 ячеек", "Вы не сможете пользоваться быстрым путешествием, если накопленная путешествиями дистанция превысит 5 ячеек",\
				"Только одно путешествие" "Вы сможете пользоваться быстрым путешествием только один раз за каждые %fastTravelTimeRestriction% час(ов)"
				Case 50 ячеек
					SetVar fastTravelmaxDistance 50
				Break
				Case 30 ячеек
					SetVar fastTravelmaxDistance 30
				Break
				Case 20 ячеек
					SetVar fastTravelmaxDistance 20
				Break
				Case 15 ячеек
					SetVar fastTravelmaxDistance 15
				Break
				Case 10 ячеек
					SetVar fastTravelmaxDistance 10
				Break
				Case 5 ячеек
					SetVar fastTravelmaxDistance 5
				Break
				Case Только одно путешествие
					SetVar fastTravelmaxDistance 0
				Break
			EndSelect
		EndIf
		
		IfNot Equal %fastTravelmaxSingleDistance% 0
			SetVar fastTravelRideFactor 1
		EndIf
		IfNot Equal %fastTravelmaxDistance% 0
			SetVar fastTravelRideFactor 1
		EndIf
		If Equal %fastTravelRideFactor% 1
			SelectWithDescriptions "Выносливость и атлетика",\
				"В 4 раза дальше" "С максимальными атлетикой и выносливостью вы сможете преодолевать быстрым путешествием в 4 раза большую дистанцию",\
				"В 3 раза дальше" "С максимальными атлетикой и выносливостью вы сможете преодолевать быстрым путешествием в 3 раза большую дистанцию",\
				"|В 2 раза дальше" "С максимальными атлетикой и выносливостью вы сможете преодолевать быстрым путешествием в 2 раза большую дистанцию",\
				"В 1.5 раза дальше" "С максимальными атлетикой и выносливостью вы сможете преодолевать быстрым путешествием в 1.5 раза большую дистанцию",\
				"В 1.2 раза дальше" "С максимальными атлетикой и выносливостью вы сможете преодолевать быстрым путешествием в 1.2 раза большую дистанцию",\
				"Не влияют" "Атлетика и выносливость не влияют на максимально возможную дистанцию быстрого путешествия."
				Case В 4 раза дальше
					SetVar fastTravelStatsFactor 4
				Break
				Case В 3 раза дальше
					SetVar fastTravelStatsFactor 3
				Break
				Case В 2 раза дальше
					SetVar fastTravelStatsFactor 2
				Break
				Case В 1.5 раза дальше
					SetVar fastTravelStatsFactor 1.5
				Break
				Case В 1.2 раза дальше
					SetVar fastTravelStatsFactor 1.2
				Break
				Case Не влияют
					SetVar fastTravelStatsFactor 1
				Break
			EndSelect
			SelectWithDescriptions "Быстрое путешествие и верховая езда",\
				"В 4 раза дальше" "При езде верхом, вы сможете преодолевать быстрым путешествием в 4 раза большую дистанцию",\
				"В 3 раза дальше" "При езде верхом, вы сможете преодолевать быстрым путешествием в 3 раза большую дистанцию",\
				"|В 2 раза дальше" "При езде верхом, вы сможете преодолевать быстрым путешествием в 2 раза большую дистанцию",\
				"В 1.5 раза дальше" "При езде верхом, вы сможете преодолевать быстрым путешествием в 1.5 раза большую дистанцию",\
				"В 1.2 раза дальше" "При езде верхом, вы сможете преодолевать быстрым путешествием в 1.2 раза большую дистанцию",\
				"Не влияет" "При езде верхом, вы сможете преодолеть быстрым путешествием ту же дистанцию, что и без лошади"
				Case В 4 раза дальше
					SetVar fastTravelRideFactor 4
				Break
				Case В 3 раза дальше
					SetVar fastTravelRideFactor 3
				Break
				Case В 2 раза дальше
					SetVar fastTravelRideFactor 2
				Break
				Case В 1.5 раза дальше
					SetVar fastTravelRideFactor 1.5
				Break
				Case В 1.2 раза дальше
					SetVar fastTravelRideFactor 1.2
				Break
			EndSelect
		EndIf
	EndIf
EndIf

SelectWithDescriptions "Контроль маркеров врат Обливиона",\
	"Ручной" "Вы сможете изменять состояние маркера врат вручную",\
	"Автоматический с маркерами закрытых" "Маркер закрытых врат сменится автоматически (с пометкой что врата закрыты)",\
	"Автоматический с удалением маркеров" "Маркеры закрытых врат будут исчезать"
	Case Ручной
		SetVar gateMode 0
	Break
	Case Автоматический с маркерами закрытых
		SetVar gateMode 1
	Break
	Case Автоматический с удалением маркеров
		SetVar gateMode 2
	Break
EndSelect	

SetVar visibleDist 0
SetVar addDist 0
SetVar revealDist 0
SetVar visibleMaxDist 0
SetVar addMaxDist 0
SetVar revealMaxDist 0
SetVar heightMax 30000
If DialogYesNo "MMO может контролировать, как и с какой дистанции маркеры карты становятся видимыми. При включении этого, вам будет предложено выбрать минимальное и максимальное расстояние для каждого случая.%NewLine%%NewLine%Дистанция видимости компаса - расстояние при котором маркеры становятся видимыми на компасе.%NewLine%Дистанция видимости карты - расстояние при котором маркеры добавляются на карту в нераскрытом состояние.%NewLine%Дистанция обнаружения - расстояние при котором маркеры полностью раскрываются на карте.%NewLine%%NewLine%Вы хотите чтобы MMO контролировал эти параметры?" "Дистанция обнаружения маркеров"

	SelectWithDescriptions "Общая максимальная дистанция при обнаружении с высоты.",\
		"Всегда максимальная (откл. контроль)" "Высота текущей местности не будет оказывать влияние на обнаружение маркеров.",\
		"15000 (Коррол)" "Максимальная дистанция обнаружения будет достигнута на высоте Коррола (и выше).",\
		"20000" "Максимальная дистанция обнаружения будет достигнута на высоте в 20000 единиц.",\
		"25000 (Брума)" "Максимальная дистанция обнаружения будет достигнута на высоте Брумы (и выше).",\
		"|30000" "Максимальная дистанция обнаружения будет достигнута на высоте в 30000 единиц.",\
		"35000 (Прыжковая скала)" "Максимальная дистанция обнаружения будет достигнута на высоте Прыжковой скалы."
		Case Всегда максимальная (откл. контроль)
			SetVar heightMax 0
		Break
		Case 15000 (Коррол)
			SetVar heightMax 15000
		Break
		Case 20000
			SetVar heightMax 20000
		Break
		Case 25000 (Брума)
			SetVar heightMax 25000
		Break
		Case 30000
			SetVar heightMax 30000
		Break
		Case 35000 (Прыжковая скала)
			SetVar heightMax 35000
		Break
	EndSelect

	IfNot Equal %heightMax% 0
		Select "Минимальная дистанция видимости компаса",\
			"12000 (ориг. игра)", "8000", "6000", "4000", "3000", "|2500 (рекомендуется)", "2000", "1500", "1000", "600", "Не контролировать"
			Case 12000 (ориг. игра)
				SetVar visibleDist 12000
			Break
			Case 8000
				SetVar visibleDist 8000
			Break
			Case 6000
				SetVar visibleDist 6000
			Break
			Case 4000
				SetVar visibleDist 4000
			Break
			Case 3000
				SetVar visibleDist 3000
			Break
			Case 2500 (рекомендуется)
				SetVar visibleDist 2500
			Break
			Case 2000
				SetVar visibleDist 2000
			Break
			Case 1500
				SetVar visibleDist 1500
			Break
			Case 1000
				SetVar visibleDist 1000
			Break
			Case 600
				SetVar visibleDist 600
			Break
		EndSelect
	
		IfNot Equal %visibleDist% 0
			Select "Максимальная дистанция видимости компаса",\
				"12000 (ориг. игра)", "8000", "|6000 (рекомендуется)", "4000", "3000", "2500", "2000", "1500", "1000"
				Case 12000 (ориг. игра)
					SetVar visibleMaxDist 12000
				Break
				Case 8000
					SetVar visibleMaxDist 8000
				Break
				Case 6000 (рекомендуется)
					SetVar visibleMaxDist 6000
				Break
				Case 4000
					SetVar visibleMaxDist 4000
				Break
				Case 3000
					SetVar visibleMaxDist 3000
				Break
				Case 2500
					SetVar visibleMaxDist 2500
				Break
				Case 2000
					SetVar visibleMaxDist 2000
				Break
				Case 1500
					SetVar visibleMaxDist 1500
				Break
				Case 1000
					SetVar visibleMaxDist 1000
				Break
			EndSelect
		EndIf

		Select "Минимальная дистанция видимости карты",\
			"10000", "8000", "6000", "4000", "3000", "|2500 (рекомендуется)", "2000", "1500", "1000", "600", "Не контролировать"
			Case 10000
				SetVar addDist 10000
			Break
			Case 8000
				SetVar addDist 8000
			Break
			Case 6000
				SetVar addDist 6000
			Break
			Case 4000
				SetVar addDist 4000
			Break
			Case 3000
				SetVar addDist 3000
			Break
			Case 2500 (рекомендуется)
				SetVar addDist 2500
			Break
			Case 2000
				SetVar addDist 2000
			Break
			Case 1500
				SetVar addDist 1500
			Break
			Case 1000
				SetVar addDist 1000
			Break
			Case 600
				SetVar addDist 600
			Break
		EndSelect

		IfNot Equal %addDist% 0
			Select "Максимальная дистанция видимости карты",\
				"10000", "8000", "|6000 (рекомендуется)", "4000", "3000", "2500", "2000", "1500", "1000", "Не контролировать"
				Case 10000
					SetVar addMaxDist 10000
				Break
				Case 8000
					SetVar addMaxDist 8000
				Break
				Case 6000 (рекомендуется)
					SetVar addMaxDist 6000
				Break
				Case 4000
					SetVar addMaxDist 4000
				Break
				Case 3000
					SetVar addMaxDist 3000
				Break
				Case 2500
					SetVar addMaxDist 2500
				Break
				Case 2000
					SetVar addMaxDist 2000
				Break
				Case 1500
					SetVar addMaxDist 1500
				Break
				Case 1000
					SetVar addMaxDist 1000
				Break
			EndSelect
		EndIf

		Select "Минимальная дистанция обнаружения",\
			"1800 (ориг. игра)", "|1500 (рекомендуется)", "1200", "1000", "800", "600", "Не контролировать"
			Case 1800 (ориг. игра)
				SetVar revealDist 1800
			Break
			Case 1500 (рекомендуется)
				SetVar revealDist 1500
			Break
			Case 1200
				SetVar revealDist 1200
			Break
			Case 1000
				SetVar revealDist 1000
			Break
			Case 800
				SetVar revealDist 800
			Break
			Case 600
				SetVar revealDist 600
			Break
		EndSelect

		IfNot Equal %revealDist% 0
			Select "Максимальная дистанция обнаружения",\
				"2000", "|1800 (рекомендуется)", "1500", "1200", "1000", "800", "Не контролировать"
				Case 2000
					SetVar revealMaxDist 2000
				Break
				Case 1800 (рекомендуется)
					SetVar revealMaxDist 1800
				Break
				Case 1500
					SetVar revealMaxDist 1500
				Break
				Case 1200
					SetVar revealMaxDist 1200
				Break
				Case 1000
					SetVar revealMaxDist 1000
				Break
				Case 800
					SetVar revealMaxDist 800
				Break
			EndSelect
		EndIf

	Else
		Select "Дистанция видимости компаса",\
			"12000 (ориг. игра)", "8000", "6000", "4000", "|3000 (рекомендуется)", "2500", "2000", "1500", "1000", "600", "Не контролировать"
			Case 12000 (ориг. игра)
				SetVar visibleDist 12000
			Break
			Case 8000
				SetVar visibleDist 8000
			Break
			Case 6000
				SetVar visibleDist 6000
			Break
			Case 4000
				SetVar visibleDist 4000
			Break
			Case 3000 (рекомендуется)
				SetVar visibleDist 3000
			Break
			Case 2500
				SetVar visibleDist 2500
			Break
			Case 2000
				SetVar visibleDist 2000
			Break
			Case 1500
				SetVar visibleDist 1500
			Break
			Case 1000
				SetVar visibleDist 1000
			Break
			Case 600
				SetVar visibleDist 600
			Break
		EndSelect

		Select "Дистанция видимости карты",\
			"10000", "8000", "6000", "4000", "|3000 (рекомендуется)", "2500", "2000", "1500", "1000", "600" "Не контролировать"
			Case 10000
				SetVar addDist 10000
			Break
			Case 8000
				SetVar addDist 8000
			Break
			Case 6000
				SetVar addDist 6000
			Break
			Case 4000
				SetVar addDist 4000
			Break
			Case 3000 (рекомендуется)
				SetVar addDist 3000
			Break
			Case 2500
				SetVar addDist 2500
			Break
			Case 2000
				SetVar addDist 2000
			Break
			Case 1500
				SetVar addDist 1500
			Break
			Case 1000
				SetVar addDist 1000
			Break
			Case 600
				SetVar addDist 600
			Break
		EndSelect

		Select "Дистанция обнаружения",\
			"1800 (ориг. игра)", "|1500 (рекомендуется)", "1200", "1000", "800", "600", "Не контролировать"
			Case 1800 (ориг. игра)
				SetVar revealDist 1800
			Break
			Case 1500 (рекомендуется)
				SetVar revealDist 1500
			Break
			Case 1200
				SetVar revealDist 1200
			Break
			Case 1000
				SetVar revealDist 1000
			Break
			Case 800
				SetVar revealDist 800
			Break
			Case 600
				SetVar revealDist 600
			Break
		EndSelect
	EndIf
EndIf

SetVar hideMapPosition 0
SetVar hidePlayerMarker 0
SetVar hideQuestMarker 0
SetVar hideHudQuestMarker 0
SetVar hideMapMarkers 0
SetVar hideNewMarkers 0
SetVar oldMarkerDistance 1.0
SetVar repositionMarkers 0
SelectManyWithDescriptions "Опции для более реалистичной карты",\
	"Скрыть все маркеры при начале новой игры", "Скрывает все маркеры карты при выходе из канализации, предотвращая возможность быстрого путешествия куда-либо до тех пор, пока вы лично не обнаружите искомую локацию",\
	"Не отображать текущую позицию", "При открытии карты мира она не будет центрироваться на игроке, таким образом вы не сразу увидите вашу текущую позицию.%NewLine%%NewLine%Это сделает ваши путешествия более увлекательными (особенно если активировать и следующую опцию...)." ,\
	"Скрыть маркер игрока", "Скрывает маркер игрока (стрелку) с карты мира.",\
	"Скрывать квестовые маркеры на карте местности", "Скрывает квестовые маркеры на карте местности, но оставляет их на карте мира.%NewLine%%NewLine%Эта опция кому-то может показаться полезной, так как вы по-прежнему будете знать основную квестовую локацию, но путь к цели придется искать самостоятельно.",\
	"Скрывать квестовые маркеры на карте местности и мира", "Скрывает квестовые маркеры и на карте местности, и на карте мира.",\
	"Скрывать квестовые маркеры на компасе", "Скрывает квестовые маркеры на компасе.",\
	"Скрывать недавно найденные маркеры", "На компасе вы будете видеть маркеры как обычно, но недавно найденные маркеры появятся на карте только при выполнении некоторых условий.%NewLine%%NewLine%Чтобы новый маркер добавился на карту вам нужно либо добраться до какого-то уже известного вам места, которое отмечено на карте, или попросить стражника отметить новый маркер на карте за небольшую плату.",\
	"Переместить оригинальные маркеры", "Перемещает многие оригинальные маркеры ближе к месту что они отмечают.%NewLine%%NewLine%Делает обнаружение маркеров значительно иммерсивным."
	Case Скрыть все маркеры при начале новой игры
		SetVar hideMapMarkers 1
	Break
	Case Не отображать текущую позицию
		SetVar hideMapPosition 1
	Break
	Case Скрыть маркер игрока
		SetVar hidePlayerMarker 1
	Break
	Case Скрывать квестовые маркеры на карте местности
		SetVar hideQuestMarker 1
	Break
	Case Скрывать квестовые маркеры на карте местности и мира
		SetVar hideQuestMarker 2
	Break
	Case Скрывать квестовые маркеры на компасе
		SetVar hideHudQuestMarker 1
	Break
	Case Скрывать недавно найденные маркеры
		SetVar hideNewMarkers 1
	Break
	Case Переместить оригинальные маркеры
		SetVar repositionMarkers 1
	Break
EndSelect

If Equal %hideMapMarkers% 1
	SelectWithDescriptions "Выбор скрытия маркеров",\
		"Скрыть в начале при выходе из канализации", "Скрыть все маркеры карты (в том числе маркеры городов и добавленные) в начале новой игры при выходе из канализации. Может не сработать, если используется мод альтернативного начала.",\
		"Скрыть в начале новой игры/чистка сохранения", "Скрыть все маркеры карты (в том числе маркеры городов и добавленные) в начале новой игры или при загрузке сохраненной игры которая была сохранена без установленного MMO."
		Case Скрыть в начале новой игры/чистка сохранения
			SetVar hideMapMarkers 2
		Break
	EndSelect
EndIf

If Equal %hideNewMarkers% 1
	Select "Цена, за которую стражник отметит вам новый маркер на карте",\
		"1 золотой за маркер", \
		"2 золотых за маркер", \
		"|5 золотых за маркер", \
		"10 золотых за маркер", \
		"20 золотых за маркер"
		Case 2 золотых за маркер
			SetVar hideNewMarkers 2
		Break
		Case 5 золотых за маркер
			SetVar hideNewMarkers 5
		Break
		Case 10 золотых за маркер
			SetVar hideNewMarkers 10
		Break
		Case 20 золотых за маркер
			SetVar hideNewMarkers 20
		Break
	EndSelect

	SelectWithDescriptions "Дистанция до раннее известного маркера",\
		"Недоступно", "Новые маркеры на карту вы сможете добавлять только с помощью стражников",\
		"50% от дистанции обнаружения", "Новый маркер будет добавлен на карту когда вы подойдете к уже известному маркеру на половину дистанции обнаружения.",\
		"100% от дистанции обнаружения", "Новый маркер будет добавлен на карту когда вы подойдете к уже известному маркеру на дистанцию обнаружения.",\
		"|150% от дистанции обнаружения", "Новый маркер будет добавлен на карту когда вы подойдете к уже известному маркеру на полторы дистанции обнаружения.",\
		"200% от дистанции обнаружения", "Новый маркер будет добавлен на карту когда вы подойдете к уже известному маркеру на две дистанции обнаружения."
		Case Недоступно
			SetVar oldMarkerDistance 0
		Break
		Case 50% от дистанции обнаружения
			SetVar oldMarkerDistance 0.5
		Break
		Case 100% от дистанции обнаружения
			SetVar oldMarkerDistance 1
		Break
		Case 150% от дистанции обнаружения
			SetVar oldMarkerDistance 1.5
		Break
		Case 200% от дистанции обнаружения
			SetVar oldMarkerDistance 2
		Break
	EndSelect
EndIf

SelectWithDescriptions "Опции создания резервных копий файлов",\
	"Резервное копирование отключено" "Резервное копирование маркеров отключено.",\
	"|Создание резервных копий вручную" "Позволяет вам вручную создавать резервные копии всех маркеров по нажатию клавиши 'M' в игре.%NewLine%%NewLine%Требует Pluggy 128 или выше!",\
	"Создавать резервные копии автоматически" "Автоматическое резервное копирование маркеров при любом их изменении. Сохранение/загрузка резервных копий производится по нажатию клавиш 'M' в игре.%NewLine%%NewLine%Требует Pluggy 128 или выше!"
	Case Резервное копирование отключено
		SetVar backupEnabled 0
	Break
	Case Создание резервных копий вручную
		SetVar backupEnabled 1
	Break
	Case Создавать резервные копии автоматически
		SetVar backupEnabled 2
	Break
EndSelect

Message "Вы можете добавлять на карту свои маркеры нажатием клавиши 'M' в игре.%NewLine%%NewLine%Переназначить ее можно в 'Ini\\Map Marker Overhaul.ini' (или добавить требование ее нажатия вместе с shift, control или alt)." "Map Marker Overhaul"

EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "visibleDistance to 2500", "visibleDistance to %visibleDist%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "addDistance to 2500", "addDistance to %addDist%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "revealDistance to 1500", "revealDistance to %revealDist%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "visibleDistanceMax to 6000", "visibleDistanceMax to %visibleMaxDist%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "addDistanceMax to 6000", "addDistanceMax to %addMaxDist%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "revealDistanceMax to 1800", "revealDistanceMax to %revealMaxDist%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "heightMax to 30000", "heightMax to %heightMax%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "FastTravelMode to 0", "FastTravelMode to %FTM%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "ayleidWells to 1", "ayleidWells to %AW%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "stones to 3", "stones to %ST%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "houses to 18", "houses to %houses%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "docks to 23", "docks to %docks%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "stables to 24", "stables to %stables%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "castles to 25", "castles to %castles%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "farms to 26", "farms to %farms%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "chapels to 27", "chapels to %chapels%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "merchants to 28", "merchants to %merchants%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "SIgates to 30", "SIgates to %SIgates%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "sewers to 31", "sewers to %sewers%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "gateMode to 1", "gateMode to %gateMode%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "hideMapPosition to 0", "hideMapPosition to %hideMapPosition%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "hidePlayerMarker to 0", "hidePlayerMarker to %hidePlayerMarker%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "hideQuestMarker to 0", "hideQuestMarker to %hideQuestMarker%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "hideHudQuestMarker to 0", "hideHudQuestMarker to %hideHudQuestMarker%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "hideMapMarkers to 0", "hideMapMarkers to %hideMapMarkers%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "backupEnabled to 1", "backupEnabled to %backupEnabled%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "fastTravelmaxSingleDistance to 0", "fastTravelmaxSingleDistance to %fastTravelmaxSingleDistance%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "fastTravelStatsFactor to 2", "fastTravelStatsFactor to %fastTravelStatsFactor%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "fastTravelRideFactor to 2", "fastTravelRideFactor to %fastTravelRideFactor%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "fastTravelTimeRestriction to 0", "fastTravelTimeRestriction to %fastTravelTimeRestriction%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "fastTravelmaxDistance to 0", "fastTravelmaxDistance to %fastTravelmaxDistance%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "hideNewMarkers to 0", "hideNewMarkers to %hideNewMarkers%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "oldMarkerDistance to 1.5", "oldMarkerDistance to %oldMarkerDistance%"
EditXMLReplace "00 Core\\Ini\\Map Marker Overhaul.ini", "repositionMarkers to 0", "repositionMarkers to %repositionMarkers%"

CopyDataFile "00 Core\\Ini\\Map Marker Overhaul.ini" "Ini\\Map Marker Overhaul.ini"
CopyDataFile "00 Core\\Ini\\Map Marker Overhaul - markers.ini" "Ini\\Map Marker Overhaul - markers.ini"
